Index: trunk/minix/lib/i86/int64/add64.s
===================================================================
--- trunk/minix/lib/i86/int64/add64.s	(revision 9)
+++ 	(revision )
@@ -1,24 +1,0 @@
-!	add64() - 64 bit addition			Author: Kees J. Bot
-!								24 Dec 1995
-.sect .text
-.define _add64
-
-_add64:				! u64_t add64(u64_t i, u64_t j);
-	push	bp
-	mov	bp, sp
-	mov	bx, 4(bp)
-	mov	ax, 6(bp)
-	add	ax, 14(bp)
-	mov	(bx), ax
-	mov	ax, 8(bp)
-	adc	ax, 16(bp)
-	mov	2(bx), ax
-	mov	ax, 10(bp)
-	adc	ax, 18(bp)
-	mov	4(bx), ax
-	mov	ax, 12(bp)
-	adc	ax, 20(bp)
-	mov	6(bx), ax
-	mov	ax, bx
-	pop	bp
-	ret
Index: trunk/minix/lib/i86/int64/add64u.s
===================================================================
--- trunk/minix/lib/i86/int64/add64u.s	(revision 9)
+++ 	(revision )
@@ -1,30 +1,0 @@
-!	add64u() - unsigned to 64 bit addition		Author: Kees J. Bot
-!								24 Dec 1995
-.sect .text
-.define _add64u, _add64ul
-
-_add64u:			! u64_t add64u(u64_t i, unsigned j);
-	push	bp
-	mov	bp, sp
-	xor	cx, cx
-	jmp	0f
-_add64ul:			! u64_t add64ul(u64_t i, unsigned long j);
-	push	bp
-	mov	bp, sp
-	mov	cx, 16(bp)
-0:	mov	bx, 4(bp)
-	mov	ax, 6(bp)
-	add	ax, 14(bp)
-	mov	(bx), ax
-	mov	ax, 8(bp)
-	adc	ax, cx
-	mov	2(bx), ax
-	mov	ax, 10(bp)
-	adc	ax, #0
-	mov	4(bx), ax
-	mov	ax, 12(bp)
-	adc	ax, #0
-	mov	6(bx), ax
-	mov	ax, bx
-	pop	bp
-	ret
Index: trunk/minix/lib/i86/int64/cmp64.s
===================================================================
--- trunk/minix/lib/i86/int64/cmp64.s	(revision 9)
+++ 	(revision )
@@ -1,52 +1,0 @@
-!	cmp64*() - 64 bit compare			Author: Kees J. Bot
-!								24 Dec 1995
-.sect .text
-.define _cmp64, _cmp64u, _cmp64ul
-
-_cmp64:				! int cmp64(u64_t i, u64_t j);
-	mov	bx, sp
-cmp64:	xor	ax, ax
-	mov	dx, 2(bx)
-	sub	dx, 10(bx)
-	mov	dx, 4(bx)
-	sbb	dx, 12(bx)
-	mov	dx, 6(bx)
-	sbb	dx, 14(bx)
-	mov	dx, 8(bx)
-	sbb	dx, 16(bx)
-	sbb	ax, ax			! ax = - (i < j)
-	mov	dx, 10(bx)
-	sub	dx, 2(bx)
-	mov	dx, 12(bx)
-	sbb	dx, 4(bx)
-	mov	dx, 14(bx)
-	sbb	dx, 6(bx)
-	mov	dx, 16(bx)
-	sbb	dx, 8(bx)
-	adc	ax, #0			! ax = (i > j) - (i < j)
-	ret
-
-_cmp64u:			! int cmp64u(u64_t i, unsigned j);
-	mov	bx, sp
-	push	16(bx)
-	mov	16(bx), #0
-	push	14(bx)
-	mov	14(bx), #0
-	push	12(bx)
-	mov	12(bx), #0
-	call	cmp64
-	pop	12(bx)
-	pop	14(bx)
-	pop	16(bx)
-	ret
-
-_cmp64ul:			! int cmp64ul(u64_t i, unsigned long j);
-	mov	bx, sp
-	push	14(bx)
-	mov	14(bx), #0
-	push	12(bx)
-	mov	12(bx), #0
-	call	cmp64
-	pop	12(bx)
-	pop	14(bx)
-	ret
Index: trunk/minix/lib/i86/int64/cv64u.s
===================================================================
--- trunk/minix/lib/i86/int64/cv64u.s	(revision 9)
+++ 	(revision )
@@ -1,21 +1,0 @@
-!	cv64u() - 64 bit converted to unsigned		Author: Kees J. Bot
-!								24 Dec 1995
-.sect .text
-.define _cv64u, _cv64ul
-
-_cv64u:				! unsigned cv64u(u64_t i);
-	mov	bx, sp
-	mov	cx, 4(bx)
-	jmp	0f
-
-_cv64ul:			! unsigned long cv64ul(u64_t i);
-	mov	bx, sp
-	xor	cx, cx
-0:	mov	ax, 2(bx)
-	mov	dx, 4(bx)
-	or	cx, 6(bx)
-	or	cx, 8(bx)		! return UINT/ULONG_MAX if really big
-	jz	0f
-	mov	ax, #-1
-	mov	dx, ax
-0:	ret
Index: trunk/minix/lib/i86/int64/cvu64.s
===================================================================
--- trunk/minix/lib/i86/int64/cvu64.s	(revision 9)
+++ 	(revision )
@@ -1,21 +1,0 @@
-!	cvu64() - unsigned converted to 64 bit		Author: Kees J. Bot
-!								24 Dec 1995
-.sect .text
-.define _cvu64, _cvul64
-
-_cvu64:				! u64_t cvu64(unsigned i);
-	mov	bx, sp
-	xor	dx, dx
-	jmp	0f
-
-_cvul64:			! u64_t cvul64(unsigned long i);
-	mov	bx, sp
-	mov	dx, 6(bx)
-0:	mov	ax, 4(bx)
-	mov	bx, 2(bx)
-	mov	(bx), ax
-	mov	2(bx), dx
-	mov	4(bx), #0
-	mov	6(bx), #0
-	mov	ax, bx
-	ret
Index: trunk/minix/lib/i86/int64/diff64.s
===================================================================
--- trunk/minix/lib/i86/int64/diff64.s	(revision 9)
+++ 	(revision )
@@ -1,10 +1,0 @@
-!	diff64() - 64 bit subtraction giving unsigned 	Author: Kees J. Bot
-!								24 Dec 1995
-.sect .text
-.define _diff64
-
-_diff64:			! unsigned diff64(u64_t i, u64_t j);
-	mov	bx, sp
-	mov	ax, 2(bx)
-	sub	ax, 10(bx)
-	ret
Index: trunk/minix/lib/i86/int64/div64u.s
===================================================================
--- trunk/minix/lib/i86/int64/div64u.s	(revision 9)
+++ 	(revision )
@@ -1,26 +1,0 @@
-!	div64u() - 64 bit divided by unsigned giving unsigned long
-!							Author: Kees J. Bot
-!								24 Dec 1995
-.sect .text
-.define _div64u, _rem64u
-
-_div64u:			! unsigned long div64u(u64_t i, unsigned j);
-	mov	bx, sp
-div64u:	xor	dx, dx
-	mov	ax, 8(bx)
-	div	10(bx)
-	mov	ax, 6(bx)
-	div	10(bx)
-	mov	ax, 4(bx)
-	div	10(bx)			! division bits 16-31
-	mov	cx, ax
-	mov	ax, 2(bx)
-	div	10(bx)			! division bits 0-15
-	xchg	dx, cx			! division in dx:ax, remainder in cx
-	ret
-
-_rem64u:			! unsigned rem64u(u64_t i, unsigned j);
-	mov	bx, sp
-	call	div64u
-	mov	ax, cx
-	ret
Index: trunk/minix/lib/i86/int64/ex64.s
===================================================================
--- trunk/minix/lib/i86/int64/ex64.s	(revision 9)
+++ 	(revision )
@@ -1,17 +1,0 @@
-!	ex64*() - extract low or high 32 bits of a 64 bit number
-!							Author: Kees J. Bot
-!								24 Dec 1995
-.sect .text
-.define _ex64lo, _ex64hi
-
-_ex64lo:			! unsigned long ex64lo(u64_t i);
-	mov	bx, sp
-	mov	ax, 2(bx)
-	mov	dx, 4(bx)
-	ret
-
-_ex64hi:			! unsigned long ex64hi(u64_t i);
-	mov	bx, sp
-	mov	ax, 6(bx)
-	mov	dx, 8(bx)
-	ret
Index: trunk/minix/lib/i86/int64/make64.s
===================================================================
--- trunk/minix/lib/i86/int64/make64.s	(revision 9)
+++ 	(revision )
@@ -1,19 +1,0 @@
-!	make64() - make a 64 bit number from two 32 bit halves
-!							Author: Kees J. Bot
-!								24 Dec 1995
-.sect .text
-.define _make64
-
-_make64:		    ! u64_t make64(unsigned long lo, unsigned long hi);
-	mov	bx, sp
-	mov	ax, 4(bx)
-	mov	dx, 6(bx)
-	mov	cx, 8(bx)
-	push	10(bx)
-	mov	bx, 2(bx)
-	mov	(bx), ax
-	mov	2(bx), dx
-	mov	4(bx), cx
-	pop	6(bx)
-	mov	ax, bx
-	ret
Index: trunk/minix/lib/i86/int64/mul64u.s
===================================================================
--- trunk/minix/lib/i86/int64/mul64u.s	(revision 9)
+++ 	(revision )
@@ -1,23 +1,0 @@
-!	mul64u() - unsigned long by unsigned multiply giving 64 bit result
-!							Author: Kees J. Bot
-!								24 Dec 1995
-.sect .text
-.define _mul64u
-
-_mul64u:			! u64_t mul64u(unsigned long i, unsigned j);
-	push	bp
-	mov	bp, sp
-	mov	bx, 4(bp)
-	mov	ax, 6(bp)
-	mul	10(bp)
-	mov	(bx), ax
-	mov	2(bx), dx
-	mov	ax, 8(bp)
-	mul	10(bp)
-	add	2(bx), ax
-	adc	dx, #0
-	mov	4(bx), dx
-	mov	6(bx), #0
-	mov	ax, bx
-	pop	bp
-	ret
Index: trunk/minix/lib/i86/int64/sub64.s
===================================================================
--- trunk/minix/lib/i86/int64/sub64.s	(revision 9)
+++ 	(revision )
@@ -1,24 +1,0 @@
-!	sub64() - 64 bit subtraction			Author: Kees J. Bot
-!								24 Dec 1995
-.sect .text
-.define _sub64
-
-_sub64:				! u64_t sub64(u64_t i, u64_t j);
-	push	bp
-	mov	bp, sp
-	mov	bx, 4(bp)
-	mov	ax, 6(bp)
-	sub	ax, 14(bp)
-	mov	(bx), ax
-	mov	ax, 8(bp)
-	sbb	ax, 16(bp)
-	mov	2(bx), ax
-	mov	ax, 10(bp)
-	sbb	ax, 18(bp)
-	mov	4(bx), ax
-	mov	ax, 12(bp)
-	sbb	ax, 20(bp)
-	mov	6(bx), ax
-	mov	ax, bx
-	pop	bp
-	ret
Index: trunk/minix/lib/i86/int64/sub64u.s
===================================================================
--- trunk/minix/lib/i86/int64/sub64u.s	(revision 9)
+++ 	(revision )
@@ -1,30 +1,0 @@
-!	sub64u() - unsigned from 64 bit subtraction	Author: Kees J. Bot
-!								24 Dec 1995
-.sect .text
-.define _sub64u, _sub64ul
-
-_sub64u:			! u64_t sub64u(u64_t i, unsigned j);
-	push	bp
-	mov	bp, sp
-	xor	cx, cx
-	jmp	0f
-_sub64ul:			! u64_t sub64ul(u64_t i, unsigned long j);
-	push	bp
-	mov	bp, sp
-	mov	cx, 16(bp)
-0:	mov	bx, 4(bp)
-	mov	ax, 6(bp)
-	sub	ax, 14(bp)
-	mov	(bx), ax
-	mov	ax, 8(bp)
-	sbb	ax, cx
-	mov	2(bx), ax
-	mov	ax, 10(bp)
-	sbb	ax, #0
-	mov	4(bx), ax
-	mov	ax, 12(bp)
-	sbb	ax, #0
-	mov	6(bx), ax
-	mov	ax, bx
-	pop	bp
-	ret